calculer l'age d'une personne dans excel Résolu

Question

bonjour, je désire savoir comment je pourrais calculer l'age d'une personne à partir de la date de sa naissance en utilisant l'excel.
merci pour votre aide

Armojax · Accepted Answer

Bonjour merazig sara,  

Si la date de naissance est en A1, tu peux écrire :  
=ENT((AUJOURDHUI()-A1)/365)  
(la personne aura 29 ans jusqu'à la veille de son anniversaire)  

ou  
=ARRONDI((AUJOURDHUI()-A1)/365;0)  
(la personne aura 30 ans dès qu'elle sera plus près de 30 que de 29).  

Etc.  

L'âge d'une personne dans Excel

jmp59 · Answer

Bonjour,

La méthode indiquée par Arjormax est bonne, mais conduit à une légère erreur, à cause des années bisextiles.
Il faut diviser par 365,25 et non 365.
Sinon la personne aura 30 ans 7 jours trop tôt !
Avec 365,25 il pourra encore y avoir une erreur, mais elle sera au maximum de 1 jour.

Bye.

BenoitC · Answer

quand on ne dispose pas de la fonction DATEDIF :
on met en A1 la date de naissance
on met dans A2 =maintenant()
on calcule l'âge (en année et mois) par la formule :
=ENT((A2-A1)/365,25)& " ans "&MOIS(A2-A1)&" mois"

et si on veut ne pas mettre "an" au pluriel lorsuqe l'âge est inférieur à 2 ans :
=ENT((A2-A1)/365,25)&SI((A2-A1)/365,25<2;" an ";" ans ")&MOIS(+A2-A1)&" mois"

ecniv · Answer

Bonjour à tous,

La formule suivante marche aussi très précise pour calculer l'âge d'une personne à une date définie :
A1 : Date de naissance
A2 : =aujourdhui()

=arrondi.inf(jours360(A1;A2)/360;0)

A+

barlou · Answer

Bonjour, je souhaiterais faire la même chose dasn excel 2007 mais ca ne marche pas.

Ca me marque #VALEUR!

J'ai déja essayé plusieur formule mais rien n'y fait.

La date de naissance se trouve en D7 et je veux me servire de la date d'aujourd'hui (=aujourdhui())

Merci d'avance

REMYK · Answer

Bonjour, suite à la formule donnée par BenoitC qui je vous le rappelle est 
=ENT((A2-A1)/365,25)& " ans "&MOIS(A2-A1)&" mois"

Cette formule est superbe mais j'ai remarqué que l'écriture de la date d'aujourdh'ui dans une cellule était supprimable en modifiant légèrement la formule.

La Voici:

En considérant que dans la cellule A1, il y a la date de naissance,

on peut écrire:

=ENT((AUJOURDHUI()-A1)/365,25)& " ans "&MOIS(AUJOURDHUI()-A1)&" mois"

Et la date reste la même sauf que l 'économie de cellule et de temps est flagrante.

breizhinours · Answer

Bonjour, j'interviens un peu tard dans la discutions...

merci pour cette formule qui m'a bien aisé aussi...
d'autre part, lorsque qu'aucune date de naissance n'est mentionnée j'obtient un chiffre : ''108'' qui en fait ''aujourd'hui/365''...

ma question : comment faire pour que le résultat (en l'occurence 108) n'apparaisse pas si il n'y a rien dans la case de la date de naissance?

merci d'avance

intello · Answer

salut
va sur ce site
http://techno.net.free.fr/spip.php?article19

Nazima · Answer

=ANNEE(aujourdhui())- ANNEE(date de naissance)
date de naissance c'est la cellule là ou vous avez tapez la date de naissance exp L1C1

f1edx · Answer

ANNEE(AUJOURDHUI()-ANNEE(B4)
OU B4 est la cellule contenant la date de naissance sous format date
a+
f1edx

ate · Answer

en A1 ecrire la date de naissance et copier cette formule en A2

=ENT((AUJOURDHUI()-A1)/365,25)& " ans "&MOIS(AUJOURDHUI()-A1)&" mois"

Ender · Answer

=ENT((AUJOURDHUI()-A1)/365,25)& " ans "&MOIS(AUJOURDHUI()-A1)-1&" mois "&JOUR(AUJOURDHUI()-A1)&"jours"

Benco · Answer

Pour aller jusqu'au bout de la logique

Années, mois, semaines et jours

=ENT((AUJOURDHUI()-A1)/365,25)& " ans "&MOIS(AUJOURDHUI()-A1)-1&" mois "&ENT(JOUR(AUJOURDHUI()-A1)/7)&" semaines et "&MOD(JOUR(AUJOURDHUI()-A1);7)&" jours"

Mike-31 · Answer

Salut, 

Je ne vois pas l'intérêt de relancer une discussion ouverte en 2006, mais pour argumenter tes dires "aller jusqu'au bout de ta logique" on ne s'appuie pas sur des moyennes 3*365+366/4 = 365,25 pour calculer une différence entre deux dates, ce genre de calcul donne un résultat avec des décimales que l'on doit tronquer ou arrondir pour un calcul qui ne couvre pas les nombres d'années multiple de 4 
la formule est donc 

=DATEDIF(A1;B1;"y")&" ans, "&DATEDIF(A1;B1;"ym")&" mois et "&DATEDIF(A1;B1;"md")&" jours"  

La formule peut être complétée pour inclure le calcul de semaine et B1 remplacé par AUJOURDHUI() pour avoir un calcul actualisé au jour le jour sur le jour courant-- 
A+ 
Mike-31 

Une période d'échec est un moment rêvé pour semer les graines du savoir.

pds_milan · Answer

Une formule qui marche quelle que soit la version d'excel et qui est 100% conforme au calcul qu'on fait de tête (même pour une date de naissance = 29/02 !!!) : 
=ANNEE(AUJOURDHUI())-ANNEE(A1)-SI(100*MOIS(AUJOURDHUI())+JOUR(AUJOURDHUI())>=100*MOIS(A1)+JOUR(A1);0;1)
avec A1 pour la date de naissance

gerard · Answer

écrire un algorithme qui permet de calculer l'age d'une personne à travers sa date de naissance

Xbrain · Answer

Voici la formule pour excel 2007+

C'est une formule exacte, sans divisions.

=ANNEE(AUJOURDHUI())-ANNEE([@[Date de naissance]]) -
SI(MOIS(AUJOURDHUI())>MOIS([@[Date de naissance]]);1;
SI(JOUR(AUJOURDHUI())>JOUR([@[Date de naissance]]);1;0))

lavegetarienne33 · Answer

Je viens d'essayer ta formule et ca a marché "Ate " sur Open office.org Writer ( feuille de calcul) 

Dans mon cas c'était pour calculer l'age de ma yorkshire a une date précise a partir de sa date de naissance 

donc dans la cellule A1 , vous mettez la date de naissance : dans mon cas 13/09/2012 

Dans la cellule A2 , 
 vous mettez la date ou vous voulez savoir l'age ce jour la : dans mon cas 19/01/2013 

Vous mettez la formule dans la cellule B1 : 

=ENT((AUJOURDHUI()-A1)/365,25)& " ans "&MOIS(AUJOURDHUI()-A1)&" mois" 

appuyer sur "entrée" et ca m'a affichée " 1 an et 3 mois " 

ps : a mon avis il arrondit en " inferieur " car sur le site ou je voulais inscrire ma York a une expo , e ils m'ont dis 1 an et 4 mois , enfin c'est pas très grave , peut etre d'ailleurs que c'est l'autre site qui arrondis " supérieurement ?! '" XD 



voila la technique , encore merci "Ate"

Mike-31 · Answer

Bonjour,

ton résultat est normal parce que pour calculer le nombre d'année, divise la différence par 365,25 qui est en fait une moyenne de quatre ans donc avec une année bissextile 365+365+365+365+366/4 
 
pour avoir un calcul plus précis il faut utiliser ce genre de formule

=DATEDIF(A1;AUJOURDHUI();"y")&" ans, "&DATEDIF(A1;AUJOURDHUI();"ym")&" mois et "&DATEDIF(A1;AUJOURDHUI();"md")&" jours"

comme cela tu pourrais jouer avec la prise en compte du pluriel des années et jours en complétant ta formule comme cela

=SI(AUJOURDHUI()-A1;TEXTE(DATEDIF(A1;AUJOURDHUI();"y");"[>1]0"" ans "";[>]""1 an "";"))&TEXTE(DATEDIF(A1;AUJOURDHUI();"ym");"[>]0"" mois "";")&SI(DATEDIF(A1;AUJOURDHUI();"md")=0;"";SI(AUJOURDHUI()-A1;TEXTE(TRONQUE(DATEDIF(A1;AUJOURDHUI();"md"));"[>1]0"" jours "";[>]""1 jour "";")))&SI(HEURE(AUJOURDHUI())-HEURE(A1)=0;"";SI(AUJOURDHUI()-A1;TEXTE(HEURE(AUJOURDHUI())-HEURE(A1);"[>1]0"" heures "";[>]""1 heure "";")))&SI(MINUTE(AUJOURDHUI())-MINUTE(A1)=0;"";SI(AUJOURDHUI()-A1;TEXTE(MINUTE(AUJOURDHUI())-MINUTE(A1);"[>1]0"" minutes "";[>]""1 minute "";")))

-
A+
Mike-31

Une période d'échec est un moment rêvé pour semer les graines du savoir.

Calculer l'age d'une personne dans excel

19 réponses

Discussions similaires

Newsletters